Oracle存储过程模板（oracle存储过程语法详解）
sinye56 2024-10-09 19:38 6 浏览 0 评论
开发存储过程模板
--存储过程，调用日志存储过程在第2个
CREATE OR REPLACE PROCEDURE SP_WA_BDXSRYGLB(V_ETLDATE IN VARCHAR2 --执行日期
,V_RETURN OUT NUMBER --0=成功，-1=失败
,V_MSG OUT VARCHAR2 --如果报错，返回报错原因及代码
)
--------------------------------------------------------------------
--功能名称 : 表关联表完整性数据跑批
--执行周期 : 平台实时调用
--创建日期 : 2020/12/30
--源表 : W_JGBDDZB;BDXSRYGLB
--目标表 : W_BDXSRYGLB
--功能描述 : 进行表的拆分处理
--版本历史 : 1.0
--作者 : PH
--------------------------------------------------------------------
IS
V_DATE_ID DATE := TO_DATE(V_ETLDATE, 'YYYYMMDD'); --执行日期
V_SCHEMA VARCHAR2(10) ; --目标表所属用户
V_PROC_START_FLAG VARCHAR2(10) ; --运行开始标记符 00：运行
V_PROC_STOP_FLAG VARCHAR2(10) ; --运行开始标记符 01：结束
V_LOG_RUN_PNAME VARCHAR2(40) ; --存储过程英文名称
V_LOG_RUN_STEP NUMBER ; --执行步数
V_LOG_RUN_TABNAME VARCHAR2(40) ; --目标表名
V_LOG_RUN_OPRTTYP VARCHAR2(10) ; --操作类型
V_LOG_RUN_MSG VARCHAR2(1024) ; --返回状态信息:执行步骤/步骤+报错信息
V_LOG_RUN_MSGFLAG VARCHAR2(10) ; --错误信息
V_LOG_RUN_COUNT NUMBER ; --总次数
V_LOG_RUN_BEGIN_TIME DATE ; --开始时间
V_LOG_RUN_RECDATE DATE ; --步骤执行时间戳
V_LOG_RUN_ETL_DATE DATE ; --ETL执行日期
BEGIN
V_SCHEMA := 'EAST' ;
V_PROC_START_FLAG := '00' ;
V_PROC_STOP_FLAG := '01' ;
V_LOG_RUN_PNAME := 'SP_WA_BDXSRYGLB' ;
V_LOG_RUN_TABNAME := 'W_BDXSRYGLB' ;
V_LOG_RUN_OPRTTYP := '' ;
V_LOG_RUN_ETL_DATE := TO_DATE(V_ETLDATE,'YYYYMMDD') ;
V_LOG_RUN_BEGIN_TIME := SYSDATE ;
--插入存储过程运行日志
ETL.SP_DMD_PROCEDURE_LOG(V_DATE_ID ,V_SCHEMA ,V_LOG_RUN_PNAME ,V_PROC_START_FLAG);
--启用oracle并行
EXECUTE IMMEDIATE 'ALTER SESSION ENABLE PARALLEL DML';
EXECUTE IMMEDIATE 'ALTER SESSION FORCE PARALLEL DML PARALLEL 16';
EXECUTE IMMEDIATE 'ALTER SESSION FORCE PARALLEL QUERY PARALLEL 16';
V_LOG_RUN_STEP := 1 ;
V_LOG_RUN_BEGIN_TIME := SYSDATE ;
V_LOG_RUN_OPRTTYP := 'DELETE';
-----------------------------------------/STEP-1:删除当前批次数据/------------------------------
DELETE FROM W_BDXSRYGLB T WHERE T.SJBSPCH = V_ETLDATE;
V_LOG_RUN_COUNT := SQL%ROWCOUNT ;
V_LOG_RUN_MSG := '执行STEP' || V_LOG_RUN_STEP || '成功';
V_LOG_RUN_RECDATE := SYSDATE ;
V_LOG_RUN_MSGFLAG := 'SUCCESS' ;
ETL.SP_DMD_PROCEDURE_STEP_LOG(V_LOG_RUN_PNAME --程序名称
,V_LOG_RUN_STEP --执行步数
,V_LOG_RUN_TABNAME --表名称
,V_LOG_RUN_OPRTTYP --数据操作类型 DELETE=删除 INSERT=新增 UPDATE=更新 SP=调用存储
,V_LOG_RUN_MSG --信息描述
,V_LOG_RUN_MSGFLAG --信息标志 FAILED=错误标识 SUCCESS=正常标志
,V_LOG_RUN_COUNT --记录条数
,V_LOG_RUN_BEGIN_TIME --开始时间
,V_LOG_RUN_RECDATE --运行日志时间
,V_LOG_RUN_ETL_DATE) --数据日期
;
COMMIT;
V_LOG_RUN_STEP := 2 ;
V_LOG_RUN_BEGIN_TIME := SYSDATE ;
V_LOG_RUN_OPRTTYP := 'INSERT';
-----------------------------------------/STEP-2:插入完整关联表数据/------------------------------------
INSERT INTO W_BDXSRYGLB(
LSH --流水号
,BXJGDM --保险机构代码
,BXJGMC --保险机构名称
,XSRYDM --销售人员代码
,XSRYXM --销售人员姓名
,YYXSRYDM --银邮销售人员代码
,YYXSRYXM --银邮销售人员姓名
)SELECT/*+parallel(8)*/
T.LSH --流水号
,T.BXJGDM --保险机构代码
,T.BXJGMC --保险机构名称
,T.XSRYDM --销售人员代码
,T.XSRYXM --销售人员姓名
,T.YYXSRYDM --银邮销售人员代码
FROM D0508_BDXSRYGLB T;
V_LOG_RUN_COUNT := SQL%ROWCOUNT ;
V_LOG_RUN_MSG := '执行STEP' || V_LOG_RUN_STEP || '成功';
V_LOG_RUN_RECDATE := SYSDATE ;
V_LOG_RUN_MSGFLAG := 'SUCCESS' ;
ETL.SP_DMD_PROCEDURE_STEP_LOG(V_LOG_RUN_PNAME --程序名称
,V_LOG_RUN_STEP --执行步数
,V_LOG_RUN_TABNAME --表名称
,V_LOG_RUN_OPRTTYP --数据操作类型
,V_LOG_RUN_MSG --信息描述
,V_LOG_RUN_MSGFLAG --信息标志 failed-错误标识 success-正常标志
,V_LOG_RUN_COUNT --记录条数
,V_LOG_RUN_BEGIN_TIME --开始时间
,V_LOG_RUN_RECDATE --运行日志时间
,V_LOG_RUN_ETL_DATE) --数据日期
;
COMMIT;
V_RETURN := 0 ;
YDETL.SP_DMD_PROCEDURE_LOG(V_DATE_ID, V_SCHEMA, V_LOG_RUN_PNAME, V_PROC_STOP_FLAG);
-----------------------------------------------/异常处理/-----------------------------------------
EXCEPTION
WHEN OTHERS THEN
ROLLBACK ;
V_LOG_RUN_MSG := 'STEP =' || V_LOG_RUN_STEP || ',ORAERROR = ' || SQLCODE || ',' || SQLERRM(SQLCODE);
V_LOG_RUN_RECDATE := SYSDATE ;
V_LOG_RUN_MSGFLAG := 'FAILED' ;
ETL.SP_DMD_PROCEDURE_STEP_LOG(V_LOG_RUN_PNAME --程序名称
,V_LOG_RUN_STEP --执行步数
,V_LOG_RUN_TABNAME --表名称
,V_LOG_RUN_OPRTTYP --数据操作类型
,V_LOG_RUN_MSG --信息描述
,V_LOG_RUN_MSGFLAG --信息标志 failed-错误标识 success-正常标志
,V_LOG_RUN_COUNT --记录条数
,V_LOG_RUN_BEGIN_TIME --开始时间
,V_LOG_RUN_RECDATE --运行日志时间
,V_LOG_RUN_ETL_DATE) --数据日期
;
V_RETURN := -1 ;
V_MSG := V_LOG_RUN_MSG;
ETL.SP_DMD_PROCEDURE_LOG(V_DATE_ID, V_SCHEMA, V_LOG_RUN_PNAME, V_PROC_STOP_FLAG);
END;
日志存储过程和建表语句
--建总日志表**************************************************************
create table ETL.DMD_PROCEDURE_LOG
(
run_etl_date DATE,
user_name VARCHAR2(30),
run_pname VARCHAR2(60),
run_status VARCHAR2(20),
run_begin_time DATE,
run_recdate DATE,
run_sql_code INTEGER,
run_sql_errm VARCHAR2(1000)
)
--建步骤日志表**************************************************************
create table ETL.DMD_PROCEDURE_STEP_LOG
(
run_pname VARCHAR2(200 CHAR),
run_step VARCHAR2(20 CHAR),
run_tabname VARCHAR2(200 CHAR),
run_oprttyp VARCHAR2(20 CHAR),
run_msg VARCHAR2(500 CHAR),
run_msgflag VARCHAR2(20 CHAR),
run_count INTEGER,
run_recdate DATE,
run_etl_date DATE,
run_begin_time DATE
)
--日志存储过程**************************************************************
CREATE OR REPLACE PROCEDURE ETL.SP_DMD_PROCEDURE_LOG(P_WORK_DATE DATE,
P_USER_NAME VARCHAR2,
P_PROCEDURE_NAME VARCHAR2,
P_PHASE_FLAG VARCHAR2 DEFAULT '00')
/*--------------------------------------------------------------------
--功能名称 : ETL运行日志记录
--执行周期 : 天
--创建日期 : 2019/1/30
--数据来源 :其他程序传参
--目标表 :DMD_PROCEDURE_LOG
--功能描述 :记录ETL存储过程运行日志
--处理逻辑： :
--版本历史 :
--------------------------------------------------------------------
--作者 ： GHC 日期 版本号 说明
--表中文名: ETL运行日志记录 2045/1/30 1.0 稳定版
--------------------------------------------------------------------
--定义存储过程信息*/
/*
参数列表：
P_WORK_DATE: 批次日期
P_PROCEDURE_NAME: 存储过程名称
P_PROC_FLAG: 运行阶段标记符【00：开始；01：结束】
*/
IS
V_NOW_TIME DATE;
V_ETL_DATE DATE;
V_USER_NAME VARCHAR2(30);
V_PROC_NAME VARCHAR2(2000);
V_SQL_CODE INTEGER;
V_SQL_ERRM VARCHAR2(1000);
BEGIN
V_SQL_CODE := SQLCODE;
V_SQL_ERRM := SUBSTR(SQLERRM, 1, 1000);
V_NOW_TIME := SYSDATE;
V_ETL_DATE := TRUNC(P_WORK_DATE, 'DD');
V_USER_NAME := UPPER(P_USER_NAME);
V_PROC_NAME := UPPER(P_PROCEDURE_NAME);
IF P_PHASE_FLAG = '00' THEN
DELETE FROM DMD_PROCEDURE_LOG A
WHERE A.RUN_ETL_DATE = V_ETL_DATE
AND A.USER_NAME = V_USER_NAME
AND A.RUN_PNAME = V_PROC_NAME
AND A.RUN_SQL_CODE = 0;
COMMIT;
INSERT INTO DMD_PROCEDURE_LOG
(RUN_ETL_DATE,
USER_NAME,
RUN_PNAME,
RUN_STATUS,
RUN_BEGIN_TIME,
RUN_RECDATE,
RUN_SQL_CODE,
RUN_SQL_ERRM)
VALUES
(V_ETL_DATE,
V_USER_NAME,
V_PROC_NAME,
'RUNNING',
V_NOW_TIME,
NULL,
NULL,
NULL);
COMMIT;
ELSIF P_PHASE_FLAG = '01' THEN
IF V_SQL_CODE = 0 THEN
UPDATE DMD_PROCEDURE_LOG A
SET A.RUN_STATUS = 'SUCCESS',
A.RUN_RECDATE = V_NOW_TIME,
A.RUN_SQL_CODE = V_SQL_CODE,
A.RUN_SQL_ERRM = V_SQL_ERRM
WHERE A.RUN_ETL_DATE = V_ETL_DATE
AND A.USER_NAME = V_USER_NAME
AND A.RUN_PNAME = V_PROC_NAME
AND A.RUN_STATUS = 'RUNNING';
COMMIT;
ELSE
UPDATE DMD_PROCEDURE_LOG A
SET A.RUN_STATUS = 'FAILED',
A.RUN_RECDATE = V_NOW_TIME,
A.RUN_SQL_CODE = V_SQL_CODE,
A.RUN_SQL_ERRM = V_SQL_ERRM
WHERE A.RUN_ETL_DATE = V_ETL_DATE
AND A.USER_NAME = V_USER_NAME
AND A.RUN_PNAME = V_PROC_NAME
AND A.RUN_STATUS = 'RUNNING';
COMMIT;
-- 如果不想继续抛出异常，则可以注释该行代码
--RAISE_APPLICATION_ERROR(-20000,V_SQL_ERRM);
END IF;
END IF;
--如果是EAST存储过程，还需要往EAST日志表中增加执行结果
IF V_USER_NAME = 'EAST' THEN
/* SELECT COUNT(1) INTO V_COUNT FROM ETL.DMD_PROCEDURE_LOG A
WHERE A.RUN_ETL_DATE = V_ETL_DATE
AND A.RUN_PNAME = V_PROC_NAME;
IF V_COUNT = 0 THEN
--RETURN;
V_RUN_STATUS := '未执行';
ELSE
SELECT DECODE(RUN_STATUS, 'SUCCESS', '通过', '不通过') INTO V_RUN_STATUS
FROM ETL.DMD_PROCEDURE_LOG A
WHERE A.RUN_ETL_DATE = V_ETL_DATE
AND A.RUN_PNAME = V_PROC_NAME;
END IF;
V_SQL := ' INSERT INTO EAST.L_FLOW_LOG (ID,TAR_TAB_NM,DATA_DATE,OBJECT_TYPE,USER_ID,BEGIN_TIME,END_TIME,RESULT)
SELECT SYS_GUID(),'
||V_TAB_NAME||',
RUN_ETL_DATE,
''20'',
''ETL'',
RUN_BEGIN_TIME,
RUN_RECDATE,'
||V_RUN_STATUS||'
FROM ETL.DMD_PROCEDURE_LOG T
WHERE T.RUN_ETL_DATE = ' ||V_ETL_DATE||
' AND T.RUN_PNAME = ' || V_PROC_NAME ;
DBMS_OUTPUT.PUT_LINE(V_SQL);
EXECUTE IMMEDIATE V_SQL;
--END IF;*/
/* INSERT INTO L_FLOW_LOG
(ID,
TAR_TAB_NM,
DATA_DATE,
OBJECT_TYPE,
USER_ID,
BEGIN_TIME,
END_TIME,
RESULT,
DESC_)
SELECT SYS_GUID() AS ID,
REPLACE(RUN_PNAME, 'SP_', '') AS TAR_TAB_NM,
RUN_ETL_DATE AS DATA_DATE,
'20' AS OBJECT_TYPE,
'ETL' AS USER_ID,
RUN_BEGIN_TIME AS BEGIN_TIME,
RUN_RECDATE AS END_TIME,
DECODE(RUN_STATUS, 'SUCCESS', '通过', '不通过') AS RESULT,
REPLACE(RUN_PNAME, 'SP_', '') || '-' ||
TO_CHAR(RUN_ETL_DATE, 'YYYYMMDD') || '-采集任务执行' ||
DECODE(RUN_STATUS, 'SUCCESS', '通过', '不通过') AS DESC_
FROM DMD_PROCEDURE_LOG T
WHERE T.RUN_ETL_DATE = V_ETL_DATE
AND T.RUN_PNAME = V_PROC_NAME;*/
COMMIT;
END IF;
END;
/
---------步骤存储过程********************************
CREATE OR REPLACE PROCEDURE ETL.SP_DMD_PROCEDURE_STEP_LOG
(
V_LOG_RUN_PNAME VARCHAR2 DEFAULT NULL,
V_LOG_RUN_STEP NUMBER DEFAULT 0,
V_LOG_RUN_TABNAME VARCHAR2 DEFAULT NULL,
V_LOG_RUN_OPRTTYP VARCHAR2 DEFAULT NULL,
V_LOG_RUN_MSG VARCHAR2 DEFAULT NULL,
V_LOG_RUN_MSGFLAG VARCHAR2 DEFAULT NULL,
V_LOG_RUN_COUNT NUMBER DEFAULT 0,
V_LOG_RUN_BEGIN_TIME DATE DEFAULT NULL,
V_LOG_RUN_RECDATE DATE DEFAULT NULL,
V_LOG_RUN_ETL_DATE DATE DEFAULT NULL
) IS
/*--------------------------------------------------------------------
--功能名称 : ETL分步骤运行日志记录
--执行周期 : 天
--创建日期 : 2045/1/30
--数据来源 :其他程序传参
--目标表 :DMD_PROCEDURE_STEP_LOG
--功能描述 :记录ETL存储过程运行分步骤日志
--处理逻辑： :
--版本历史 :
--------------------------------------------------------------------
--作者 ： GHC 日期 版本号 说明
--表中文名: ETL分步骤运行日志记录 2045/1/30 1.0 稳定版
--------------------------------------------------------------------
--定义存储过程信息*/
BEGIN
--获取日志参数信息
DELETE FROM DMD_PROCEDURE_STEP_LOG T
WHERE T.RUN_PNAME=V_LOG_RUN_PNAME
AND (T.RUN_ETL_DATE=V_LOG_RUN_ETL_DATE OR T.RUN_ETL_DATE IS NULL)
AND (T.RUN_STEP = V_LOG_RUN_STEP OR T.RUN_STEP IS NULL);
COMMIT;
--插入日志参数到系统运行日志信息表
INSERT INTO DMD_PROCEDURE_STEP_LOG( RUN_PNAME --程序名称
,RUN_STEP --执行步
,RUN_TABNAME --表名称
,RUN_OPRTTYP --数据操作类型
,RUN_MSG --信息描述
,RUN_MSGFLAG --信息标志 failed-错误标志 success-正常标志
,RUN_COUNT --记录条数
,RUN_BEGIN_TIME --开始时间
,RUN_RECDATE --运行日志时间
,RUN_ETL_DATE --数据日期
)
VALUES(
V_LOG_RUN_PNAME
,V_LOG_RUN_STEP
,V_LOG_RUN_TABNAME
,V_LOG_RUN_OPRTTYP
,V_LOG_RUN_MSG
,V_LOG_RUN_MSGFLAG
,V_LOG_RUN_COUNT
,V_LOG_RUN_BEGIN_TIME
,V_LOG_RUN_RECDATE
,V_LOG_RUN_ETL_DATE
);
--IF SQLCODE = 0 THEN
--成功 提交
COMMIT;
--ELSE
--失败 回滚
--RUN_MSG:='执行失败'||'ORAERROR = '||SQLCODE||','||SQLERRM(SQLCODE);
-- ROLLBACK;
--end if ;
end SP_DMD_PROCEDURE_STEP_LOG;
/
相关推荐
- 一个不错的软件版本命名规范!
-
之前写了一篇如何自动生成版本号的文章，《让你的C程序，自动打印版本信息》初衷是让自己的程序在运行时自动打印与版本相关的信息，避免测试时因为版本信息不确定导致的一些功能对应不上去的问题，当时留了一个坑，...
- 国产操作系统迎来发展风口 公务领域更能培育起Linux生态
-
谷歌和微软在俄罗斯市场的一番套路猛如虎，就让我们深刻地意识到了，只有自己的东西才能靠得住。也由此，国内操作系统发展迎来了发展风口。我就看到有朋友就秀出了他们单位采购的纯国产的主机，一款华为的主机，纯国...
- 5个大有“前途”的Linux桌面发行版本
-
ZD至顶网CIO与应用频道08月27日专栏：Linux无处不在。你的服务器里，你的电话、汽车、手表、烤面包机、冰箱……和台式机里都有Linux的身影。虽然在桌面上见到Linux的用户比在自动调温...
- Linux 常用应用软件大全
-
编译自：https://www.fossmint.com/most-used-linux-applications/作者：MartinsD.Okoi译者：HankChow对于许多应用程序...
- Linux 4.1 系列的最大版本 4.1.18 LTS发布，带来大量修改
-
（LCTT译注：这是一则过期的消息，但是为了披露更新内容，还是发布出来给大家参考）著名的内核维护者GregKroah-Hartman貌似正在度假中，因为SashaLevin2016年2月16日的...
- Linux发行版需要杀软吗?卡巴斯基推出免费KVRT病毒扫描清理工具
-
IT之家6月4日消息，你认为使用Linux发行版，需要杀毒软件吗？或许很多用户认为Linux发行版偏小众，因此受到黑客攻击的风险也相对较小，不过卡巴斯基并不这么认为，近期推出了适用于...
- 适合开发人员的 5款 Linux 发行版
-
什么是Linux？Linux是基于Unix的操作系统。由LinusTorvalds开发于1991年首次发布其内核。因为Linux是开源软件，其发行版由不同组织发布，因此不同的发行版具有不同的风格...
- VMware Workstation 17.0 Pro 发布:新增 TPM 2.0 完美兼容Win11
-
IT之家11月18日消息，VMwareWorkstation17.0Pro现已发布，它带来了许多新特性，例如微软Windows11硬性要求：虚拟可信平台模块(TPM)2.0。...
- 你是否需要一个容器专用的Linux发行版本?
-
单单使用容器是不够的,提供商们认为你需要一个容器专用的Linux发行版本。我们可以让容器在不同的操作系统上运行，不同的操作系统都有自己的虚拟化服务，如：SolarisZones、BSDJails、...
- Tizen 3.0版本发布 采用Linux 4.1内核
-
2015-09-2111:31:39作者：马荣【中关村在线软件资讯】9月21日消息：尽管三星靠着Android系统设备在移动市场赚钱，但是仍然没有忘记自家的Tizen开发。现在Tizen3.0版...
- 欧拉操作系统演进:应用累计超130万套 支持鲲鹏、英特尔、飞腾等芯片
-
21世纪经济报道记者倪雨晴深圳报道4月15日，在欧拉开发者大会（openEulerDeveloperDay2022）的主论坛上，欧拉首个数字基础设施全场景长周期版openEuler22.03...
- Papyros:以Material Design为灵感的Linux发行版本
-
项目团队并不希望只是采用传统的桌面主题，而是致敬谷歌Android系统的MaterialDesign设计语言想要打造出某些不同以往足够吸引用户的Linux发行版本，自然该版本还在不断的更新和改进中，...
- 比特网早报:全国空间计量技术委员会成立，银河麒麟操作系统上架微信Linux4.0.0版本
-
2024年11月6日消息，昨夜今晨，科技圈都发生了哪些大事？行业大咖抛出了哪些新的观点？比特网为您带来值得关注的科技资讯：全国空间计量技术委员会在北京成立近日，经市场监管总局批准，全国空间计量技术委员...
- 2024年最稳定的5个Linux发行版，赶紧收藏!
-
Linux是最流行的免费开源平台之一。Linux已被广泛使用，因为它安全、可扩展和灵活。Linux发行版收集开源代码，对其进行编译，并将其组合成一个可以轻松启动和安装的操作系统。它们还提供不同的...
- 彰显Linux生态繁华，Ubuntu、Fedora等四发行版同时发布新版本
-
上周对于开源社区来说是忙碌的一周。EndeavourOS和TrueNASScale于周二（4月16日）发布，Fedora于周三（4月17日）发布，Ubuntu于周四（4月18日）发布。四个新版本中都...
欢迎 你 发表评论:
- 一周热门
- 最近发表
- 标签列表
-
- oracle忘记用户名密码 (59)
- oracle11gr2安装教程 (55)
- mybatis调用oracle存储过程 (67)
- oracle spool的用法 (57)
- oracle asm 磁盘管理 (67)
- 前端 设计模式 (64)
- 前端面试vue (56)
- linux格式化 (55)
- linux图形界面 (62)
- linux文件压缩 (75)
- Linux设置权限 (53)
- linux服务器配置 (62)
- mysql安装linux (71)
- linux启动命令 (59)
- 查看linux磁盘 (72)
- linux用户组 (74)
- linux多线程 (70)
- linux设备驱动 (53)
- linux自启动 (59)
- linux网络命令 (55)
- linux传文件 (60)
- linux打包文件 (58)
- linux查看数据库 (61)
- linux获取ip (64)
- linux进程通信 (63)